/*
 * Licensed to the Apache Software Foundation (ASF) under one
 * or more contributor license agreements.  See the NOTICE file
 * distributed with this work for additional information
 * regarding copyright ownership.  The ASF licenses this file
 * to you under the Apache License, Version 2.0 (the
 * "License"); you may not use this file except in compliance
 * with the License.  You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing,
 * software distributed under the License is distributed on an
 * "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
 * KIND, either express or implied.  See the License for the
 * specific language governing permissions and limitations
 * under the License.
 */

import groovy.json.JsonBuilder
import org.apache.tinkerpop.gremlin.language.corpus.FeatureReader
import org.apache.tinkerpop.gremlin.language.translator.GremlinTranslator
import org.apache.tinkerpop.gremlin.language.translator.Translator
import org.apache.tinkerpop.gremlin.language.translator.TranslatorException

import java.nio.file.Paths

// file is overwritten on each generation
def outputFile = new File("${projectBaseDir}/gremlin-test/src/main/resources/org/apache/tinkerpop/gremlin/language/translator/translations.json")

// assumes globally unique scenario names for keys with list of Gremlin traversals as they appear
def gremlins = FeatureReader.parseGrouped(Paths.get("${projectBaseDir}", "gremlin-test", "src", "main", "resources", "org", "apache", "tinkerpop", "gremlin", "test", "features").toString())

def scenarios = gremlins.collect { scenarioName, traversals ->
    def translatedTraversals = traversals.collect { original ->
        def entry = [original: original]
        Translator.values().each { translator ->
            try {
                def language = translator.name().toLowerCase()
                entry[language] = GremlinTranslator.translate(original, translator).getTranslated()
            } catch (TranslatorException ignored) {
                // entry[language] stays undefined/null
            } catch (Exception ignored) {
                // entry[language] stays undefined/null
            }
        }
        return entry
    }

    return [scenario: scenarioName, traversals: translatedTraversals]
}

def json = new JsonBuilder(scenarios)
outputFile.withWriter('UTF-8') { writer ->
    writer.write(json.toPrettyString())
}
